Rinominare gruppo di file

[AntFast]

Ciao a tutti
Sapete come si fa a rinominare un gruppo di file in una
cartella togliendo a tutti i primi "n" caratteri ?
Nell'esempio sono da togliere i primi 16 caratteri:
da a
NomeStessoAlbum-File1.mp3 File1.mp3
NomeStessoAlbum-File2.mp3 File2.mp3
NomeStessoAlbum-File3.mp3 File3.mp3
ecc....

Grazie in anticpo per l'eventuale risposta.
AntFast

[AntFast]

Ciao a tutti
Sapete come si fa, in un file batch, a rinominare un gruppo
di file in una > cartella togliendo a tutti i primi "n" caratteri ?
Nell'esempio sono da togliere i primi 16 caratteri:
da a
NomeStessoAlbum-File1.mp3 File1.mp3
NomeStessoAlbum-File2.mp3 File2.mp3
NomeStessoAlbum-File3.mp3 File3.mp3
ecc....

Grazie in anticpo per l'eventuale risposta.
AntFast

[Roberto Mariottini]

Post by AntFast
Sapete come si fa a rinominare un gruppo di file in una
cartella togliendo a tutti i primi "n" caratteri ?
da a
NomeStessoAlbum-File1.mp3 File1.mp3
NomeStessoAlbum-File2.mp3 File2.mp3
NomeStessoAlbum-File3.mp3 File3.mp3
ecc....

Con Windows XP:

==============================================
@echo off
setlocal enabledelayedexpansion

if not "%1"=="" goto run
echo Sintassi: %0 [numero di caratteri da eliminare]
goto end

:run
for %%i in (*.mp3) do (
set F=%%i
echo ren "!F!" "!F:~%1!"
)

:end
==============================================

Lo salvi come renn.bat e lo usi così

renn 16

per eliminare i primi 16 caratteri.

Fai prima un po' di prove, poi togli "echo" davnti a "ren" per rinominare
veramente.

Post by AntFast
Grazie in anticpo per l'eventuale risposta.

Prego.

Ciao
---
http://www.mariottini.net/roberto/

[AntFast]

"Roberto Mariottini" <***@mail.com> ha scritto nel messaggio news:ej9dme$57i$***@news.newsland.it...
[cut..]
rinominare un gruppo di file ...

Post by Roberto Mariottini

Post by AntFast
da a
NomeStessoAlbum-File1.mp3 File1.mp3
NomeStessoAlbum-File2.mp3 File2.mp3
NomeStessoAlbum-File3.mp3 File3.mp3
ecc....

@echo off
setlocal enabledelayedexpansion
if not "%1"=="" goto run
echo Sintassi: %0 [numero di caratteri da eliminare]
goto end
:run
for %%i in (*.mp3) do (
set F=%%i
echo ren "!F!" "!F:~%1!"
)
:end

Ciao Roberto e davvero grazie, spendido..!
Una ciliegina... :-)
E' possibile lanciare il file.bat con il parametro richiesto
restando nella cartella di windows xp ?
AntFast

AntFast.

[Roberto Mariottini]

Post by AntFast
E' possibile lanciare il file.bat con il parametro richiesto
restando nella cartella di windows xp ?

Direi di sì, ma credo di non aver capito bene la domanda.

Ciao
---
http://www.mariottini.net/roberto/
SuperbCalc: http://www.mariottini.net/roberto/superbcalc/

[AntFast]

Post by Roberto Mariottini

Post by AntFast
E' possibile lanciare il file.bat con il parametro richiesto
restando nella cartella di windows xp ?

Direi di sì, ma credo di non aver capito bene la domanda.
Ciao

La domanda e' :
Sono in una cartella di Windows, es. C.\Lavoro\Vasco Rossi.
In essa ci sono vari file mp3 che devo rinominare, es.
da:
Vasco Rossi - 1.o brano
Vasco Rossi - 2.o brano
ecc.
a:
1.o brano
2.o brano
ecc.
Quindi, stando alla bat che mi hai insegnato a costruire,
chiamata Bat Mariottini e messa nella cartella nascosta:
"c:\documents and settings\nome utente\sendto"
in questo caso dovrei lanciarla col parametro 14
(per togliere i primi 14 caratteri).
Seleziono i file da rinominare, tasto destro del mouse,
invia a -> Bat Mariottini.... quindi, il parametro come
faccio a passarglielo ?
E' importante il parametro proprio perche' posso avere
la necessita' di ri_operare con un numero di caratteri da
togliere diverso da 14... (lo so che per te e' ovvio... :-) )
Con stima
AntFast

[Roberto Mariottini]

Sono in una cartella di Windows, es. C.LavoroVasco Rossi.
In essa ci sono vari file mp3 che devo rinominare, es.
Vasco Rossi - 1.o brano
Vasco Rossi - 2.o brano
ecc.
1.o brano
2.o brano
ecc.
Quindi, stando alla bat che mi hai insegnato a costruire,
"c:documents and settingsnome utentesendto"
in questo caso dovrei lanciarla col parametro 14
(per togliere i primi 14 caratteri).
Seleziono i file da rinominare, tasto destro del mouse,
invia a -> Bat Mariottini.... quindi, il parametro come
faccio a passarglielo ?

Chiamalo renn.bat:

==============================================
@echo off
setlocal enabledelayedexpansion

set N=%1
if "%N%"=="" (
set /P N=Numero di caratteri da eliminare:
)

for %%i in (*.mp3) do (
set F=%%i
echo ren "!F!" "!F:~%N%!"
)
==============================================

Ciao
---
http://www.mariottini.net/roberto/
SuperbCalc: http://www.mariottini.net/roberto/superbcalc/

[Andrea]

Post by Roberto Mariottini
==============================================
@echo off
setlocal enabledelayedexpansion
if not "%1"=="" goto run
echo Sintassi: %0 [numero di caratteri da eliminare]
goto end
:run
for %%i in (*.mp3) do (
set F=%%i
echo ren "!F!" "!F:~%1!"
)
:end
==============================================
Lo salvi come renn.bat e lo usi così
renn 16
per eliminare i primi 16 caratteri.

Scusa, cosa fa la riga setlocal enabledelayedexpansion ?

Andrea.

[Roberto Mariottini]

Post by Andrea
Scusa, cosa fa la riga setlocal enabledelayedexpansion ?

Fa funzionare !F! invece di %F%.
In pratica se usi %F% in un FOR la cosa non funziona a dovere perché
l'espansione della variabile F avviene al momento del parsing del comando
FOR e in seguito non cambia più.
Abilitando la "delayed expansion", quindi usando !F! al posto di %F%,
l'espansione della variabile F avviene ad ogni ciclo, quindi cambia col
variare della variabile F.

Ciao
---
http://www.mariottini.net/roberto/
SuperbCalc: http://www.mariottini.net/roberto/superbcalc/